# Find the subjects and objects of a given predict, such as "ncit:P97" (DEFINITION)

PREFIX ncit: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
SELECT ?s ?o
FROM  <http://ncicb.nci.nih.gov/xml/owl/EVS/ThesaurusInf.rdf>
WHERE { ?s ncit:P97 ?o . }
ORDER BY ?s LIMIT 100

# Find all subclasses (children) of a given class, such as "ncit:C19540" (Cancer Gene), and return the subclasses with their associated relations and objects

prefix ncit:  <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
prefix rdfs:  <http://www.w3.org/2000/01/rdf-schema#>
prefix owl:  <http://www.w3.org/2002/07/owl#>
select ?sub_label ?rel_label ?obj_label
from <http://ncicb.nci.nih.gov/xml/owl/EVS/ThesaurusInf.rdf>
where {
  VALUES ?superclass { ncit:C19540 }
  ?subject rdfs:subClassOf+ ?superclass ;
           rdfs:label ?sub_label .
  OPTIONAL {
      ?subject ?relation ?object . 
      ?relation a owl:ObjectProperty ; 
                rdfs:label ?rel_label . 
      ?object rdfs:label ?obj_label .
  }
}
order by asc(?sub_label)  limit 500

# Find all annotations and annotated property values of a given class, such as "ncit:C50577" (Heart Failure)

prefix ncit: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix owl: <http://www.w3.org/2002/07/owl#>

select DISTINCT ?subject ?prop_label ?prop_value ?annotations
from <http://ncicb.nci.nih.gov/xml/owl/EVS/ThesaurusInf.rdf>
where {
  values ?subject { ncit:C50577 }
  ?subject ?prop ?prop_value .
  ?prop rdfs:label ?prop_label ;
    a owl:AnnotationProperty .

  optional {
    SELECT DISTINCT ?subject ?prop ?prop_value 
           (GROUP_CONCAT(?annot ; separator=' | ') AS ?annotations)
    where {
      ?an a owl:Axiom ;
         owl:annotatedSource ?subject ;
         owl:annotatedProperty ?prop ;
         owl:annotatedTarget ?prop_value ;
            ?annotation ?annot_value .
      ?annotation rdfs:label ?annotation_label .
      BIND( CONCAT( ?annotation_label , '=' , ?annot_value ) AS ?annot )
      } GROUP BY ?subject ?an ?prop ?prop_value
   }
}
order by ?prop_label
limit 100

# Find data elements where the main concept of the object class has a label containing a specific string such as "Person"

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dr: <http://cbiit.nci.nih.gov/caDSR#>
prefix idr: <http://www.iso.org/11179/MDR#>
prefix ncit: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>

select distinct ?concept_label 
       (group_concat(?data_element ; separator=', ') as ?data_elements) 
       (COUNT(?data_element) as ?element_count)
FROM <http://cbiit.nci.nih.gov/caDSR>
FROM <http://ncicb.nci.nih.gov/xml/owl/EVS/ThesaurusInf.rdf>
where {
 ?data_element idr:Object_Class [ dr:main_concept ?concept ] .
 ?concept rdfs:label ?concept_label .
 ?concept_label bif:contains "person" .
 FILTER NOT EXISTS { ?concept rdfs:label "Person" }
}
order by desc(?element_count) limit 10

# Check if a class, such as "ncit:C18145" (Informatics), under class "Gene"

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix ncit: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
ASK {
  GRAPH <http://ncicb.nci.nih.gov/xml/owl/EVS/ThesaurusInf.rdf> {
      ncit:C18145 rdfs:subClassOf+ ?super .
      ?super rdfs:label "Gene" .
  }
}

# Describe a given resource, such as "ncit:C18369". It returns triples that either subject or object is "ncit:C18369".

prefix ncit: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
DESCRIBE ncit:C18369
from <http://ncicb.nci.nih.gov/xml/owl/EVS/ThesaurusInf.rdf>